%--------------------------------- - - - - - - - - - -  -  -  -  -   -
% SICStus PROLOG: Declaracoes iniciais

:- use_module(library(random)).
:- set_prolog_flag( discontiguous_warnings,off ).
:- set_prolog_flag( single_var_warnings,off ).
:- set_prolog_flag( unknown,fail ).

%--------------------------------- - - - - - - - - - -  -  -  -  -   -
% SICStus PROLOG: definicoes iniciais

:- op( 900,xfy,:: ).
:- op( 900,xfy,::: ).
:- op( 800,fx,se ).
:- op( 800,fx,tratamento ).
:- op( 900,xfy,'com grau de confiança').
:- op( 800,xfy,porque).
:- op( 700,xfx,entao ).
:- op( 300,xfy,ou ).
:- op( 200,xfy,e ).

:- dynamic facto/1.
:- dynamic '::' /2.
:- dynamic ':::' /2.

%--------------------------------- - - - - - - - - - -  -  -  -  -   -
% meta-predicado nao

nao( QUESTAO ) :-
    QUESTAO, !, fail.
nao( QUESTAO ).

%--------------------------------- - - - - - - - - - -  -  -  -  -   -
% predicados menor e maior

menor(G1, G2,G1) :-
	G1=<G2.
menor(G1, G2, G2) :-
	G2<G1.


maior(G1, G2,G2) :-
	G1=<G2.
maior(G1, G2, G1) :-
	G2<G1.

%--------------------------------- - - - - - - - - - -  -  -  -  -   -
% meta-predicado medico_backward

medico_backward( DIAGNOSTICO,DIAGNOSTICO 'com grau de confiança' Gp ):-
    facto( DIAGNOSTICO ) :: G,
	grau_confiança(Gp,G).

medico_backward( DIAGNOSTICO,(DIAGNOSTICO 'com grau de confiança' Gp)  porque X,tratamento TRATAMENTO ) :-
    (se SINTOMA entao DIAGNOSTICO) :: (Gr,TRATAMENTO),
    medico_preliminar( SINTOMA,Gc,X ),
	G is Gr*Gc,
	grau_confiança(Gp,G).

medico_preliminar( DIAGNOSTICO,G,DIAGNOSTICO 'com grau de confiança' Gp ):-
    facto( DIAGNOSTICO ) :: G,
	grau_confiança(Gp,G).

medico_preliminar( DIAGNOSTICO,G,(DIAGNOSTICO 'com grau de confiança' Gp)  porque X ) :-
    (se SINTOMA entao DIAGNOSTICO) :: (Gr,TRATAMENTO),
    medico_preliminar( SINTOMA,Gc,X ),
	G is Gr*Gc,
	grau_confiança(Gp,G).

medico_preliminar( DIAGNOSTICO1 e DIAGNOSTICO2,G,X e Y 'com grau de confiança' Gp ) :-
    nonvar(DIAGNOSTICO1), nonvar(DIAGNOSTICO2),
	medico_preliminar( DIAGNOSTICO1,G1,X ),
    medico_preliminar( DIAGNOSTICO2,G2,Y ),
    menor( G1,G2,G ),
	grau_confiança(Gp,G).

medico_preliminar( DIAGNOSTICO1 ou DIAGNOSTICO2,G1,X ) :-
	 nonvar(DIAGNOSTICO1), nonvar(DIAGNOSTICO2),
	medico_preliminar( DIAGNOSTICO1,G1,X ),
	nao(medico_preliminar( DIAGNOSTICO2,G2,Y )).


medico_preliminar( DIAGNOSTICO1 ou DIAGNOSTICO2,G2,X ) :-
         nonvar(DIAGNOSTICO1), nonvar(DIAGNOSTICO2),
	medico_preliminar( DIAGNOSTICO2,G2,X ),
	nao(medico_preliminar(DIAGNOSTICO1,G1,Y)).

medico_preliminar( DIAGNOSTICO1 ou DIAGNOSTICO2,G,X ou Y 'com grau de confiança' Gp ) :-
	 nonvar(DIAGNOSTICO1), nonvar(DIAGNOSTICO2),
	medico_preliminar(DIAGNOSTICO1, G1,X),
	medico_preliminar(DIAGNOSTICO2, G2,Y),
	maior(G1,G2,G),
	grau_confiança(Gp,G).

%--------------------------------- - - - - - - - - - -  -  -  -  -   -
% meta-predicado medico_forward

medico_forward( CONCLUSAO 'com grau de confiança' Gp,tratamento TRATAMENTO  ) :-
    (se CONDICAO entao CONCLUSAO) :: (G,TRATAMENTO),
    composicao( CONDICAO,Gr ),
	Gn is G*Gr,
	grau_confiança(Gp,Gn),
   	 inserir_sintomas( facto(CONCLUSAO) :: Gn,numerico ).

medico_preliminar2( CONCLUSAO,Gn ) :-
    (se CONDICAO entao CONCLUSAO) :: (G,TRATAMENTO),
    composicao( CONDICAO,Gr ),
    Gn is G*Gr,
   	 inserir_sintomas( facto(CONCLUSAO) :: Gn,numerico ).


composicao( CONDICAO,G ) :-
    facto(CONDICAO) :: G.

composicao( CONDICAO1 e CONDICAO2,G ) :-
    composicao( CONDICAO1,G1 ),
    composicao( CONDICAO2,G2 ),
	maior(G1,G2,G).

composicao( CONDICAO1 ou CONDICAO2,G1 ) :-
	nonvar(CONDICAO1), nonvar(CONDICAO2),
	composicao( CONDICAO1,G1 ),
	nao(composicao( CONDICAO2,G2)).

composicao( CONDICAO1 ou CONDICAO2,G2 ) :-
   nonvar(CONDICAO1), nonvar(CONDICAO2),
	composicao( CONDICAO2,G2 ),
	nao(composicao( CONDICAO1,G1)).

composicao( CONDICAO1 ou CONDICAO2,G ) :-
    composicao( CONDICAO1,G1 ),
    composicao( CONDICAO2,G2 ),
	menor(G1,G2,G).

composicao( CONDICAO,G ) :-
    medico_preliminar2( CONDICAO,G ).

remover_sintomas :- retractall(facto(FACTO) :: G).

%--------------------------------- - - - - - - - - - -  -  -  -  -   -
% predicado grau_confiança

grau_confiança('impossivel',G) :- G=0.

grau_confiança('vagamente provavel',G) :- 0<G,G<0.4.

grau_confiança('provavel',G) :- 0.4=<G,G<0.7.

grau_confiança('fortemente provavel',G) :- 0.7=<G,G<1.

grau_confiança('certo',G) :- G=1.

%--------------------------------- - - - - - - - - - -  -  -  -  -   -
% predicado atribuir

atribuir(0,'impossivel').

atribuir(X,'vagamente provavel') :- random(0.0000001,0.4000001,X).

atribuir(X,'provavel') :- random(0.4,0.6999999,X).

atribuir(X,'fortemente provavel') :- random(0.7,0.9999999,X).

atribuir(1,'certo').

%--------------------------------- - - - - - - - - - -  -  -  -  -   -
% predicado inserir_sintomas

inserir_sintomas( Termo :: G,qualitativo) :-
    solucoes( Invariante,+(Termo :: G):::Invariante,Lista ),
    atribuir(H,G),
    insercao( Termo :: H ),
    teste( Lista ).

inserir_sintomas( Termo :: G,numerico) :-
    solucoes( Invariante,+(Termo :: G):::Invariante,Lista ),
    insercao( Termo :: G ),
    teste( Lista ).

%--------------------------------- - - - - - - - - - -  -  -  -  -   -
% invariante que impede a insercao de sintomas repetidos

+(facto(D) :: T) ::: (solucoes((D),(facto(D) :: K),S),comprimento(S,N), N==1).

%--------------------------------- - - - - - - - - - -  -  -  -  -   -
% predicados auxiliares para insercao de termos 

teste( [] ).
teste( [R|LR] ) :-
    R,
    teste( LR ).


solucoes( X,Y,Z ) :-
    findall( X,Y,Z ).

comprimento( S,N ) :-
    length( S,N ).

insercao( Termo ):-
	assert( Termo ).
insercao( Termo ):-
	retract( Termo ),!,fail.

%--------------------------------- - - - - - - - - - -  -  -  -  -   -
% Regras de produção


(se frequencia_cardiaca(lenta) entao bradicardia) :: (1,'administracao de atropina'). 

(se frequencia_cardiaca(rapida) entao taquicardia) :: (1,'dieta alimentar'). 

(se frequencia_cardiaca(rapida) e frequencia_cardiaca(irregular) entao arritmia) :: (1,cardioversao).

(se taquicardia e consumo(cafe) entao 'taquicardia paroxistica') :: (0.6,tossir).

(se taquicardia e consumo(cafe) entao 'taquicardia paroxistica') :: (0.6,'suspender a respiraçao por 1 minuto').

(se taquicardia e consumo(alcool) entao 'taquicardia paroxistica') :: (0.6,'imergir a cabeça em água fria').

(se emagrecimento e diarreia e flatulencia entao dispepsia) :: (0.3,gastroscopia). 

(se diarreia e flatulencia e 'mau halito' entao dispepsia) :: (3.0,'saneamento bucal').

(se flatulencia e 'ausencia de odor' entao anosmia) :: (0.8,'remoçao de polipos nasais').

(se fractura ou traumatismo entao inchaço) :: (0.8,'colocar gelo').

%--------------------------------- - - - - - - - - - -  - -  -  -   -